Gentoo Packages

sys-boot/palo - 9999 (gentoo)

Search

Install

Install this version:

emerge -a =sys-boot/palo-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =sys-boot/palo-9999

Or alternatively:

emerge --autounmask-write -a =sys-boot/palo-9999

Package Information

Description:
PALO: PArisc Linux Loader
Homepage:
https://parisc.wiki.kernel.org/ https://git.kernel.org/pub/scm/linux/kernel/git/deller/palo.git/
License:
GPL-2

Ebuild Details

Version EAPI Keywords Slot
9999 8 -* ~hppa 0
View Raw Ebuild 
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="PALO: PArisc Linux Loader"
HOMEPAGE="https://parisc.wiki.kernel.org/ https://git.kernel.org/pub/scm/linux/kernel/git/deller/palo.git/"

if [[ ${PV} == 9999 ]] ; then
	EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/deller/palo.git"
	inherit git-r3
else
	SRC_URI="https://git.kernel.org/pub/scm/linux/kernel/git/deller/${PN}.git/snapshot/${P}.tar.gz"
	KEYWORDS="-* ~hppa"
fi

LICENSE="GPL-2"
SLOT="0"

PATCHES=(
	"${FILESDIR}"/${PN}-2.28-toolchain.patch
)

src_compile() {
	local target
	for target in '-C palo' '-C ipl' 'iplboot'; do
		emake AR="$(tc-getAR)" CC="$(tc-getCC)" LD="$(tc-getLD)" ${target}
	done
}

src_install() {
	into /
	dosbin palo/palo

	insinto /usr/share/palo
	doins iplboot

	insinto /etc
	doins "${FILESDIR}"/palo.conf

	insinto /etc/kernel/postinst.d
	insopts -m 0744
	doins "${FILESDIR}"/99palo

	doman palo.8

	dodoc TODO debian/changelog README.html
}

Inherited Eclasses

toolchain-funcs
git-r3