Gentoo Packages

sys-fs/genimage - 9999 (gentoo)

Search

Install

Install this version:

emerge -a =sys-fs/genimage-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =sys-fs/genimage-9999

Or alternatively:

emerge --autounmask-write -a =sys-fs/genimage-9999

Package Information

Description:
Tool to generate multiple filesystem and flash images from a tree
Homepage:
https://github.com/pengutronix/genimage
License:
GPL-2

Ebuild Details

Version EAPI Keywords Slot
9999 8 ~amd64 ~arm ~arm64 0
View Raw Ebuild 
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools optfeature

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/pengutronix/genimage.git"
else
	SRC_URI="https://github.com/pengutronix/genimage/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~arm64"
fi

DESCRIPTION="Tool to generate multiple filesystem and flash images from a tree"
HOMEPAGE="https://github.com/pengutronix/genimage"

LICENSE="GPL-2"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"

DEPEND="dev-libs/confuse:="
RDEPEND="${DEPEND}"
BDEPEND="test? ( sys-apps/fakeroot )"

src_prepare() {
	default
	eautoreconf
}

pkg_postinst() {
	optfeature "cpio support" app-alternatives/cpio
	optfeature "tar support" app-arch/tar
	optfeature "qemu support" app-emulation/qemu
	optfeature "dosfstools support" sys-fs/dosfstools
	optfeature "cramfs support" sys-fs/cramfs
	optfeature "genext2fs support" sys-fs/genext2fs
	optfeature "jffs, ubifs and ubinize support" sys-fs/mtd-utils
	optfeature "squashfs support" sys-fs/squashfs-tools
}

USE Flags

Manage flags for this package: euse -i <flag> -p sys-fs/genimage | euse -E <flag> -p sys-fs/genimage | euse -D <flag> -p sys-fs/genimage

Global/Standard Flags

test

Inherited Eclasses

autotools
optfeature
git-r3

Dependencies

DEPEND

dev-libs/confuse:=

RDEPEND

dev-libs/confuse:=

BDEPEND

test? ( sys-apps/fakeroot )