Gentoo Packages

Search

Install

Install this version:

emerge -a =sys-kernel/cachyos-settings-1.3.5

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =sys-kernel/cachyos-settings-1.3.5

Or alternatively:

emerge --autounmask-write -a =sys-kernel/cachyos-settings-1.3.5

Package Information

Description:: Configuration files and tweaks from CachyOS
Homepage:: https://github.com/CachyOS/CachyOS-Settings
License:: GPL-3

Ebuild Details

Version	EAPI	Keywords	Slot
1.3.5	8	~amd64	0

View Raw Ebuild

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the BSD 3-Clause License

EAPI=8

inherit udev tmpfiles systemd

DESCRIPTION="Configuration files and tweaks from CachyOS"
HOMEPAGE="https://github.com/CachyOS/CachyOS-Settings"
SRC_URI="https://github.com/CachyOS/CachyOS-Settings/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/CachyOS-Settings-${PV}"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="systemd zram"
REQUIRED_USE="zram? ( systemd )"

RDEPEND="
	app-shells/bash
	sys-apps/hdparm
	sys-apps/pciutils
	sys-process/procps
	virtual/udev
	zram? (
		sys-apps/zram-generator
		app-arch/zstd
	)
"

src_install() {
	insinto /etc/security/limits.d/
	doins etc/security/limits.d/20-audio.conf

	dobin usr/bin/{dlss-swapper,dlss-swapper-dll,pci-latency,zink-run}
	if use systemd; then
		dobin usr/bin/game-performance
		dobin usr/bin/kerver
	fi

	insinto /usr/lib/modprobe.d
	doins usr/lib/modprobe.d/{amdgpu,blacklist,nvidia}.conf

	insinto /usr/lib/modules-load.d
	doins usr/lib/modules-load.d/ntsync.conf

	insinto /usr/lib/sysctl.d
	doins usr/lib/sysctl.d/70-cachyos-settings.conf

	if use systemd; then
		local systemd_utildir
		systemd_utildir="$(systemd_get_utildir)"
		systemd_utildir="${systemd_utildir#"${EPREFIX}"}"

		insinto "${systemd_utildir}/journald.conf.d"
		doins usr/lib/systemd/journald.conf.d/00-journal-size.conf

		insinto "${systemd_utildir}/system.conf.d"
		doins usr/lib/systemd/system.conf.d/{00-timeout,10-limits}.conf

		systemd_dounit usr/lib/systemd/system/pci-latency.service

		insinto "${systemd_utildir}/system"
		doins -r  usr/lib/systemd/system/{rtkit-daemon,user@}.service.d

		insinto "${systemd_utildir}/user.conf.d"
		doins usr/lib/systemd/user.conf.d/{00-timeout,10-limits}.conf

		if use zram; then
			insinto "${systemd_utildir}"
			doins usr/lib/systemd/zram-generator.conf
		fi
	fi

	dotmpfiles usr/lib/tmpfiles.d/{coredump,thp-shrinker,thp}.conf

	udev_dorules usr/lib/udev/rules.d/{20-audio-pm,30-zram,40-hpet-permissions,50-sata,60-ioschedulers,69-hdparm,71-nvidia,99-cpu-dma-latency}.rules

	insinto /usr/share/X11/xorg.conf.d
	doins usr/share/X11/xorg.conf.d/20-touchpad.conf
}

pkg_postinst() {
	udev_reload
	tmpfiles_process {coredump,thp-shrinker,thp}.conf
}

pkg_postrm() {
	udev_reload
}

USE Flags

Manage flags for this package: euse -i <flag> -p sys-kernel/cachyos-settings | euse -E <flag> -p sys-kernel/cachyos-settings | euse -D <flag> -p sys-kernel/cachyos-settings

Global/Standard Flags

systemd

zram

Inherited Eclasses

udev

tmpfiles