Gentoo Packages

dev-python/auditok - 0.2.0 (guru)

Search

Install

Install this version:

emerge -a =dev-python/auditok-0.2.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/auditok-0.2.0

Or alternatively:

emerge --autounmask-write -a =dev-python/auditok-0.2.0

Package Information

Description:
A module for Audio/Acoustic Activity Detection
Homepage:
https://github.com/amsehili/auditok/
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
0.2.0 8 ~amd64 0
View Raw Ebuild 
# Copyright 2021-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..13} )

inherit distutils-r1 optfeature

DESCRIPTION="A module for Audio/Acoustic Activity Detection"
HOMEPAGE="https://github.com/amsehili/auditok/"
SRC_URI="https://github.com/amsehili/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"

IUSE="test"
RESTRICT="!test? ( test )"

BDEPEND="
	test? (
		dev-python/pydub[${PYTHON_USEDEP}]
		dev-python/genty[${PYTHON_USEDEP}]
		dev-python/matplotlib[${PYTHON_USEDEP}]
	)
	"

distutils_enable_tests unittest

python_prepare_all() {
	distutils-r1_python_prepare_all

	# these tests appear to be broken
	rm "${S}"/tests/test_plotting.py || die
}

python_test() {
	eunittest tests/
}

pkg_postinst() {
	optfeature "reading audio files in popular audio formats (ogg, mp3, etc.) or extracting audio from a video file" dev-python/pydub
	optfeature "reading audio data from the microphone and playing audio back" dev-python/pyaudio
	optfeature "showing progress bar while playing audio clips" dev-python/tqdm
	optfeature "plotting audio signal and detections" dev-python/matplotlib
	optfeature "matplotlib. Also used for some math operations instead of standard python if available" dev-python/numpy
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/auditok | euse -E <flag> -p dev-python/auditok | euse -D <flag> -p dev-python/auditok

Global/Standard Flags

test

Inherited Eclasses

distutils-r1
optfeature

Dependencies

BDEPEND

	test? (
		dev-python/pydub[]
		dev-python/genty[]
		dev-python/matplotlib[]
	)

Manifest for 0.2.0

Type File Size Source URLs
DIST auditok-0.2.0.tar.gz 2482517 bytes https://github.com/amsehili/auditok/archive/refs/tags/v0.2.0.tar.gz