Gentoo Packages

dev-python/jpype - 1.7.1 (guru)

Search

Install

Install this version:

emerge -a =dev-python/jpype-1.7.1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/jpype-1.7.1

Or alternatively:

emerge --autounmask-write -a =dev-python/jpype-1.7.1

Package Information

Description:
Bridge to allow Python programs full access to Java class libraries
Homepage:
https://github.com/jpype-project/jpype/
License:
Apache-2.0

Ebuild Details

Version EAPI Keywords Slot
1.7.1 8 ~amd64 0
View Raw Ebuild 
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=scikit-build-core
PYTHON_COMPAT=( python3_{12..15} )
EPYTEST_PLUGINS=()

inherit java-pkg-2 distutils-r1

DESCRIPTION="Bridge to allow Python programs full access to Java class libraries"
HOMEPAGE="https://github.com/jpype-project/jpype/"
SRC_URI="
	https://github.com/jpype-project/jpype/archive/refs/tags/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	dev-python/packaging[${PYTHON_USEDEP}]
	>=virtual/jre-11:*
"

DEPEND=">=virtual/jdk-11:*"

BDEPEND="
	${DEPEND}
	>=dev-python/scikit-build-core-0.9[${PYTHON_USEDEP}]
	dev-java/ant
	test? (
		dev-python/jedi[${PYTHON_USEDEP}]
		dev-python/numpy[${PYTHON_USEDEP}]
	)
"

distutils_enable_tests pytest

PATCHES=(
	"${FILESDIR}/${P}-java-release.patch"
	"${FILESDIR}/${P}-jar-location.patch"
)

python_compile() {
	local DISTUTILS_ARGS=( -DBUILD_TEST_HARNESS=$(usex test ON OFF) )
	distutils-r1_python_compile
}

python_test() {
	cd test || die

	epytest jpypetest --checkjni \
		--ignore=jpypetest/test_sql_h2.py \
		--ignore=jpypetest/test_sql_hsqldb.py \
		--ignore=jpypetest/test_sql_sqlite.py
}

Inherited Eclasses

java-pkg-2
distutils-r1

Dependencies

DEPEND

>=virtual/jdk-11:*

RDEPEND

	dev-python/packaging[]
	>=virtual/jre-11:*

BDEPEND

	>=virtual/jdk-11:*
	>=dev-python/scikit-build-core-0.9[]
	dev-java/ant
	test? (
		dev-python/jedi[]
		dev-python/numpy[]
	)

Manifest for 1.7.1

Type File Size Source URLs
DIST jpype-1.7.1.gh.tar.gz 802748 bytes https://github.com/jpype-project/jpype/archive/refs/tags/v1.7.1.tar.gz