Gentoo Packages

Search

Install

Install this version:

emerge -a =dev-python/pyfiglet-1.0.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pyfiglet-1.0.2

Or alternatively:

emerge --autounmask-write -a =dev-python/pyfiglet-1.0.2

Package Information

Description:: Pure-python FIGlet implementation
Homepage:: https://pypi.org/project/pyfiglet/ https://github.com/pwaller/pyfiglet
License:: MIT BSD HPND MIT NTP contrib? ( all-rights-reserved )

Ebuild Details

Version	EAPI	Keywords	Slot
1.0.2	8	~amd64	0

View Raw Ebuild

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{12..13} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1

DESCRIPTION="Pure-python FIGlet implementation"
HOMEPAGE="
	https://pypi.org/project/pyfiglet/
	https://github.com/pwaller/pyfiglet
"
# no tests in pypi sdist
SRC_URI="https://github.com/pwaller/pyfiglet/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="MIT"
# bundled fonts: https://src.fedoraproject.org/rpms/python-pyfiglet/blob/rawhide/f/python-pyfiglet.spec
LICENSE+=" BSD HPND MIT NTP contrib? ( all-rights-reserved )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="contrib"

PATCHES=(
	"${FILESDIR}/${P}-fix-test.patch"
)

distutils_enable_tests pytest

src_prepare() {
	mv pyfiglet/fonts-standard pyfiglet/fonts || die
	if use contrib; then
		mv pyfiglet/fonts-contrib/* pyfiglet/fonts || die
	fi
	distutils-r1_src_prepare
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/pyfiglet | euse -E <flag> -p dev-python/pyfiglet | euse -D <flag> -p dev-python/pyfiglet

Global/Standard Flags

contrib

Inherited Eclasses

distutils-r1

Manifest for 1.0.2

Type	File	Size	Source URLs
DIST	pyfiglet-1.0.2.gh.tar.gz	1660490 bytes	https://github.com/pwaller/pyfiglet/archive/refs/tags/v1.0.2.tar.gz

dev-python/pyfiglet - 1.0.2 (guru)