Gentoo Packages

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit meson optfeature shell-completion xdg

DESCRIPTION="A lightweight Wayland shell and bar built directly on Wayland + OpenGL ES"
HOMEPAGE="https://noctalia.dev/ https://github.com/noctalia-dev/noctalia"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/noctalia-dev/noctalia.git"
else
	SRC_URI="https://github.com/noctalia-dev/noctalia/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="MIT"
SLOT="0"

IUSE="+jemalloc"

DEPEND="
	dev-cpp/nlohmann_json
	dev-cpp/sdbus-c++
	dev-cpp/tomlplusplus
	dev-libs/glib:2
	jemalloc? ( dev-libs/jemalloc:= )
	dev-libs/libxml2
	dev-libs/md4c
	dev-libs/stb
	dev-libs/libical
	dev-libs/libsodium
	dev-libs/wayland
	app-crypt/libsecret
	gnome-base/librsvg:2
	media-libs/fontconfig
	media-libs/freetype
	media-libs/libjxl
	media-libs/libsndfile
	media-libs/libwebp
	media-libs/mesa
	media-video/pipewire
	media-video/wireplumber
	net-misc/curl
	sci-libs/libqalculate
	sys-auth/polkit
	sys-libs/pam
	virtual/opengl
	x11-libs/cairo[glib]
	x11-libs/libxkbcommon
	x11-libs/pango
"

RDEPEND="
	${DEPEND}
	dev-vcs/git
"

BDEPEND="
	dev-libs/wayland
	dev-libs/wayland-protocols
	dev-util/wayland-scanner
"

DOCS=( {README,CREDITS}.md example.toml )

src_configure() {
	local emesonargs=(
		$(meson_feature jemalloc)
	)
	meson_src_configure
}

src_compile() {
	meson_src_compile

	"${BUILD_DIR}"/${PN} completions bash > ${PN}.bash || die
	"${BUILD_DIR}"/${PN} completions zsh > ${PN}.zsh || die
	"${BUILD_DIR}"/${PN} completions fish > ${PN}.fish || die
}

src_install() {
	meson_src_install

	newbashcomp "${PN}.bash" "${PN}"
	dofishcomp "${PN}.fish"
	newzshcomp "${PN}.zsh" "_${PN}"
}

pkg_postinst() {
	xdg_pkg_postinst

	optfeature "external display brightness control" app-misc/ddcutil
	optfeature "battery and power device integration" sys-power/upower
	optfeature "clipboard auto-paste" gui-apps/wtype
	optfeature "hardware-accelerated screen recording" media-video/gpu-screen-recorder
}