net-mail/hydroxide - 0.2.33 (guru)

Search

Install

Install this version:

emerge -a =net-mail/hydroxide-0.2.33

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =net-mail/hydroxide-0.2.33

Or alternatively:

emerge --autounmask-write -a =net-mail/hydroxide-0.2.33

Package Information

Description:
A third-party, open-source ProtonMail CardDAV, IMAP and SMTP bridge
Homepage:
https://codeberg.org/emersion/hydroxide
License:
MIT BSD MIT

Ebuild Details

Version EAPI Keywords Slot
0.2.33 8 ~amd64 0
View Raw Ebuild
# Copyright 2022-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module multiprocessing

if [[ "${PV}" == "9999" ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://codeberg.org/emersion/${PN}.git"
else
	inherit verify-sig
	SRC_URI="https://codeberg.org/emersion/${PN}/releases/download/v${PV}/${P}.tar.gz
		verify-sig? ( https://codeberg.org/emersion/${PN}/releases/download/v${PV}/${P}.tar.gz.sig )
		https://github.com/ingenarel/${PN}/releases/download/v${PV}/${P}-deps.tar.xz
	"
	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/emersion.asc"
	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-emersion )"
	KEYWORDS="~amd64"
fi
DESCRIPTION="A third-party, open-source ProtonMail CardDAV, IMAP and SMTP bridge"
HOMEPAGE="https://codeberg.org/emersion/hydroxide"

LICENSE="MIT"
#gentoo-go-license hydroxide-0.2.33.ebuild
LICENSE+=" BSD MIT "
SLOT="0"
BDEPEND+=" >=dev-lang/go-1.26.0"
DOCS=( README.md )

src_unpack() {
	if [[ ${PV} == *9999* ]]; then
		git-r3_src_unpack
		go-module_live_vendor
	else
		if use verify-sig; then
			verify-sig_verify_detached "${DISTDIR}/${P}".tar.gz{,.sig}
		fi
		go-module_src_unpack
	fi
}

src_compile() {
	ego build -v -x -p "$(get_makeopts_jobs)" ./cmd/hydroxide
}

src_test() {
	ego test ./...
}

src_install() {
	default
	dobin "${PN}"
}

Inherited Eclasses

Dependencies

BDEPEND

verify-sig? ( sec-keys/openpgp-keys-emersion )  >=dev-lang/go-1.26.0

Manifest for 0.2.33

Type File Size Source URLs
DIST hydroxide-0.2.33-deps.tar.xz 53927808 bytes https://github.com/ingenarel/hydroxide/releases/download/v0.2.33/hydroxide-0.2.33-deps.tar.xz
DIST hydroxide-0.2.33.tar.gz 46465 bytes https://codeberg.org/emersion/hydroxide/releases/download/v0.2.33/hydroxide-0.2.33.tar.gz
DIST hydroxide-0.2.33.tar.gz.sig 931 bytes https://codeberg.org/emersion/hydroxide/releases/download/v0.2.33/hydroxide-0.2.33.tar.gz.sig