net-proxy/snowflake - 2.15.3 (guru)

Search

Install

Install this version:

emerge -a =net-proxy/snowflake-2.15.3

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =net-proxy/snowflake-2.15.3

Or alternatively:

emerge --autounmask-write -a =net-proxy/snowflake-2.15.3

Package Information

Description:
Pluggable Transport using WebRTC, inspired by Flashproxy
Homepage:
https://snowflake.torproject.org https://gitlab.torproject.org/tpo/anti-censorship/pluggable-transports/snowflake
License:
BSD Apache-2.0 BSD-2 CC0-1.0 MIT

Ebuild Details

Version EAPI Keywords Slot
2.15.3 8 ~amd64 0
View Raw Ebuild
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module systemd

DESCRIPTION="Pluggable Transport using WebRTC, inspired by Flashproxy"
HOMEPAGE="
	https://snowflake.torproject.org
	https://gitlab.torproject.org/tpo/anti-censorship/pluggable-transports/snowflake
"
SRC_URI="https://dist.torproject.org/snowflake/${PV}/snowflake-v${PV}.tar.gz"
S=${WORKDIR}/snowflake-v${PV}

LICENSE="BSD Apache-2.0 BSD-2 CC0-1.0 MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="minimal"

BDEPEND=">=dev-lang/go-1.26.10"

src_configure() {
	COMPONENTS=(
		proxy
		$(usev !minimal "broker client probetest server")
	)
	einfo "The following components will be built: ${COMPONENTS[@]}"
}

src_compile() {
	local component
	for component in "${COMPONENTS[@]}"; do
		pushd ${component} || die
		einfo "Building ${component}"
		nonfatal ego build || die "${component}: build failed"
		popd || die
	done
}

src_test() {
	ego test ./...
}

src_install() {
	local component
	for component in "${COMPONENTS[@]}"; do
		newbin ${component}/${component} snowflake-${component}
		newdoc ${component}/README.md README_${component}.md
	done

	systemd_dounit "${FILESDIR}"/snowflake-proxy.service
	newinitd "${FILESDIR}"/snowflake-proxy.initd snowflake-proxy

	einstalldocs
	dodoc doc/*.txt doc/*.md
	doman doc/*.1
}

USE Flags

Manage flags for this package: euse -i <flag> -p net-proxy/snowflake | euse -E <flag> -p net-proxy/snowflake | euse -D <flag> -p net-proxy/snowflake

Global/Standard Flags

Inherited Eclasses

Dependencies

BDEPEND

>=dev-lang/go-1.26.10

Manifest for 2.15.3

Type File Size Source URLs
DIST snowflake-v2.15.3.tar.gz 20244957 bytes https://dist.torproject.org/snowflake/2.15.3/snowflake-v2.15.3.tar.gz