Gentoo Packages

# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop optfeature xdg verify-sig

DESCRIPTION="The Mullvad Browser is developed to minimize tracking and fingerprinting"
HOMEPAGE="https://github.com/mullvad/mullvad-browser/ https://mullvad.net/"
SRC_NAME="https://github.com/mullvad/mullvad-browser/releases/download/${PV}/mullvad-browser-linux-x86_64-${PV}.tar.xz"
SRC_URI="
	${SRC_NAME} -> ${P}.tar.xz
	verify-sig? ( ${SRC_NAME}.asc -> ${P}.tar.xz.asc )
"

S="${WORKDIR}"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="-* ~amd64"

IUSE="X"

RDEPEND="
	app-accessibility/at-spi2-core
	app-misc/mime-types
	dev-libs/dbus-glib
	dev-libs/glib
	dev-libs/nspr
	dev-libs/nss
	gui-libs/gtk
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	media-video/ffmpeg
	sys-apps/dbus
	sys-libs/glibc
	x11-libs/cairo
	x11-themes/hicolor-icon-theme
	x11-libs/libX11
	x11-libs/libxcb
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXt
	x11-libs/libXtst
	x11-libs/gdk-pixbuf
	x11-libs/gtk+
	x11-libs/libXext
	x11-libs/pango
"
BDEPEND="
	verify-sig? ( sec-keys/openpgp-keys-mullvad-browser-bin )
"

QA_PREBUILT="*"

src_unpack() {
	VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/mullvad-browser-bin.asc
	default
}

src_install() {
	# Install profiles to home dir
	touch mullvad-browser/Browser/is-packaged-app || die

	# Fix desktop file vars
	sed -i \
		-e 's|Name=.*|Name=Mullvad Browser|g' \
		-e 's|Exec=.*|Exec=/opt/mullvad-browser/Browser/start-mullvad-browser --detach|g' \
		-e 's|Icon=.*|Icon=mullvad-browser|g' \
		mullvad-browser/start-mullvad-browser.desktop || die

	insinto /opt/
	doins -r mullvad-browser

	dosym ../../opt/mullvad-browser/Browser/start-mullvad-browser /usr/bin/${PN}
	domenu mullvad-browser/start-mullvad-browser.desktop
	local x
	for x in 16 32 48 64 128; do
		newicon -s ${x} mullvad-browser/Browser/browser/chrome/icons/default/default${x}.png mullvad-browser.png
	done

	fperms 755 /opt/mullvad-browser/Browser/abicheck
	fperms +x /opt/mullvad-browser/Browser/glxtest
	fperms +x /opt/mullvad-browser/Browser/vaapitest
	fperms +x /opt/mullvad-browser/Browser/start-mullvad-browser
	fperms +x /opt/mullvad-browser/Browser/mullvadbrowser
	fperms +x /opt/mullvad-browser/Browser/mullvadbrowser.real
}

pkg_postinst() {
	xdg_pkg_postinst
	optfeature "wayland screensharing support" sys-apps/xdg-desktop-portal
}