Gentoo Packages

dev-python/boto3 - 1.42.86 (ha-bleeding-edge)

Search

Install

Install this version:

emerge -a =dev-python/boto3-1.42.86

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/boto3-1.42.86

Or alternatively:

emerge --autounmask-write -a =dev-python/boto3-1.42.86

Package Information

Description:
The AWS SDK for Python
Homepage:
https://github.com/boto/boto3/ https://pypi.org/project/boto3/
License:
Apache-2.0

Ebuild Details

Version EAPI Keywords Slot
1.42.86 8 amd64 arm arm64 x86 0
View Raw Ebuild 
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1

DESCRIPTION="The AWS SDK for Python"
HOMEPAGE="
	https://github.com/boto/boto3/
	https://pypi.org/project/boto3/
"
SRC_URI="
	https://github.com/boto/boto3/archive/${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm arm64 x86"

RDEPEND="
	>=dev-python/botocore-1.42.86[${PYTHON_USEDEP}]
	<dev-python/botocore-1.43.0[${PYTHON_USEDEP}]
	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
	<dev-python/jmespath-2.0.0[${PYTHON_USEDEP}]
	>=dev-python/s3transfer-0.16.0[${PYTHON_USEDEP}]
	<dev-python/s3transfer-0.17.0[${PYTHON_USEDEP}]
"

EPYTEST_XDIST=1
distutils_enable_tests pytest

python_prepare_all() {
	# don't lock versions to narrow ranges
	sed -e '/botocore/ d' \
		-e '/jmespath/ d' \
		-e '/s3transfer/ d' \
		-i setup.py || die

	# do not rely on bundled deps in botocore (sic!)
	find -name '*.py' -exec sed -i \
		-e 's:from botocore[.]vendored import:import:' \
		-e 's:from botocore[.]vendored[.]:from :' \
		{} + || die

	distutils-r1_python_prepare_all
}

python_test() {
	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
	epytest tests/{functional,unit}
}

Inherited Eclasses

distutils-r1

Dependencies

RDEPEND

	>=dev-python/botocore-1.42.86[]
	<dev-python/botocore-1.43.0[]
	>=dev-python/jmespath-0.7.1[]
	<dev-python/jmespath-2.0.0[]
	>=dev-python/s3transfer-0.16.0[]
	<dev-python/s3transfer-0.17.0[]

Manifest for 1.42.86

Type File Size Source URLs
DIST boto3-1.42.86.gh.tar.gz 1118949 bytes https://github.com/boto/boto3/archive/1.42.86.tar.gz