Gentoo Packages

dev-python/dnspython - 2.9.1 (ha-bleeding-edge)

Search

Install

Install this version:

emerge -a =dev-python/dnspython-2.9.1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/dnspython-2.9.1

Or alternatively:

emerge --autounmask-write -a =dev-python/dnspython-2.9.1

Package Information

Description:
DNS toolkit for Python
Homepage:
https://www.dnspython.org/ https://github.com/rthalley/dnspython/ https://pypi.org/project/dnspython/
License:
ISC

Ebuild Details

Version EAPI Keywords Slot
2.9.1 8 ~amd64 ~arm64 0
View Raw Ebuild 
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=uv-build
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 pypi

DESCRIPTION="DNS toolkit for Python"
HOMEPAGE="
	https://www.dnspython.org/
	https://github.com/rthalley/dnspython/
	https://pypi.org/project/dnspython/
"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="dnssec examples https quic"

RDEPEND="
	dnssec? (
		>=dev-python/cryptography-50[${PYTHON_USEDEP}]
	)
	https? (
		>=dev-python/httpx-0.26.0[${PYTHON_USEDEP}]
		>=dev-python/h2-4.4[${PYTHON_USEDEP}]
	)
	quic? ( >=dev-python/aioquic-1.3.0[${PYTHON_USEDEP}] )
"
BDEPEND="
	test? (
		>=dev-python/cryptography-50[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
EPYTEST_XDIST=1
distutils_enable_tests pytest

python_test() {
	local -x NO_INTERNET=1
	epytest
}

python_install_all() {
	distutils-r1_python_install_all
	if use examples; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}

USE Flags

Manage flags for this package: euse -i <flag> -p dev-python/dnspython | euse -E <flag> -p dev-python/dnspython | euse -D <flag> -p dev-python/dnspython

Global/Standard Flags

dnssec
examples
https
quic

Inherited Eclasses

distutils-r1
pypi

Dependencies

RDEPEND

	dnssec? (
		>=dev-python/cryptography-50[]
	)
	https? (
		>=dev-python/httpx-0.26.0[]
		>=dev-python/h2-4.4[]
	)
	quic? ( >=dev-python/aioquic-1.3.0[] )

BDEPEND

	test? (
		>=dev-python/cryptography-50[]
	)