dev-python/pyfakefs - 6.3.2 (ha-bleeding-edge)

Search

Install

Install this version:

emerge -a =dev-python/pyfakefs-6.3.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/pyfakefs-6.3.2

Or alternatively:

emerge --autounmask-write -a =dev-python/pyfakefs-6.3.2

Package Information

Description:
A fake file system that mocks the Python file system modules
Homepage:
https://github.com/pytest-dev/pyfakefs/ https://pypi.org/project/pyfakefs/
License:
Apache-2.0

Ebuild Details

Version EAPI Keywords Slot
6.3.2 8 ~amd64 ~arm64 0
View Raw Ebuild
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1

DESCRIPTION="A fake file system that mocks the Python file system modules"
HOMEPAGE="
	https://github.com/pytest-dev/pyfakefs/
	https://pypi.org/project/pyfakefs/
"
SRC_URI="
	https://github.com/pytest-dev/pyfakefs/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64"

EPYTEST_PLUGINS=( "${PN}" )
distutils_enable_tests pytest

python_test() {
	local EPYTEST_DESELECT=(
		# requires *.dist-info/RECORD file that we're stripping
		pyfakefs/tests/fake_filesystem_test.py::RealFileSystemAccessTest::test_add_package_metadata
		# wants dev-python/openpyxl
		pyfakefs/tests/patched_packages_test.py::TestPatchedPackages::test_read_excel
	)
	local EPYTEST_IGNORE=(
		# test for regression with opentimelineio package
		pyfakefs/pytest_tests/segfault_test.py
		# test for regression with undefined package
		pyfakefs/pytest_tests/pytest_fixture_test.py
	)

	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
		EPYTEST_IGNORE+=(
			pyfakefs/pytest_tests/pytest_reload_pandas_test.py
		)
	fi

	epytest
}

Inherited Eclasses

Manifest for 6.3.2

Type File Size Source URLs
DIST pyfakefs-6.3.2.gh.tar.gz 266072 bytes https://github.com/pytest-dev/pyfakefs/archive/v6.3.2.tar.gz