app-misc/node-red - 5.0.10 (inode64-overlay)

Search

Install

Install this version:

emerge -a =app-misc/node-red-5.0.10

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =app-misc/node-red-5.0.10

Or alternatively:

emerge --autounmask-write -a =app-misc/node-red-5.0.10

Package Information

Description:
A visual tool for wiring the Internet of Things
Homepage:
https://nodered.org
License:
Apache-2.0

Ebuild Details

Version EAPI Keywords Slot
5.0.10 8 ~amd64 0
View Raw Ebuild
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit nodejs nodejs-mod systemd tmpfiles

DESCRIPTION="A visual tool for wiring the Internet of Things"
HOMEPAGE="https://nodered.org"
SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/${PV}.tar.gz  -> ${P}.tar.gz
		https://www.inode64.com/dist/${P}-node_modules.tar.xz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	acct-user/node-red
	>=net-libs/nodejs-22.9[npm]
"

NODEJS_EXTRA_FILES="packages"

# @node-rs/bcrypt (napi-rs, Rust) is only shipped as a prebuilt binary.
# https://github.com/inode64/inode64-overlay/issues/29
QA_PREBUILT="usr/lib*/node_modules/${PN}/node_modules/@node-rs/*/*.node"

src_install() {
	# Remove jsdoc-nr-template, prune use git to get the version
	rm -rf node_modules/jsdoc-nr-template/ || die
	sed -i -e '/jsdoc-nr-template/d' package.json || die

	nodejs-mod_src_install

	# The root package.json is the monorepo one, which declares no commands.
	local red="$(nodejs_modules)/packages/node_modules/${PN}/red.js"
	fperms +x "${red}"
	dosym -r "${red}" /usr/bin/${PN}

	dotmpfiles "${FILESDIR}"/node-red.conf

	doinitd "${FILESDIR}"/${PN}
	systemd_dounit "${FILESDIR}/${PN}.service"
}

pkg_postinst() {
	tmpfiles_process node-red.conf
}

Inherited Eclasses

Dependencies

RDEPEND

	acct-user/node-red
	>=net-libs/nodejs-22.9[npm]

Manifest for 5.0.10

Type File Size Source URLs
DIST node-red-5.0.10-node_modules.tar.xz 49455092 bytes https://www.inode64.com/dist/node-red-5.0.10-node_modules.tar.xz
DIST node-red-5.0.10.tar.gz 9098658 bytes https://github.com/node-red/node-red/archive/refs/tags/5.0.10.tar.gz