Gentoo Packages

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop

DESCRIPTION="Graphical viewer for GNU ddrescue mapfiles"
HOMEPAGE="https://sourceforge.net/projects/ddrescueview/"
SRC_URI="
	https://sourceforge.net/projects/ddrescueview/files/Test%20builds/v${PV}/ddrescueview-source-${PV}.tar.xz/download -> ${P}.tar.xz
"
S="${WORKDIR}/ddrescueview-source-${PV}"

# unknown whether 3-or-later is explicit
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"

# VDB: detected possibly incorrect RDEPEND (app-misc/ddrescueview-0.4.5)
# added all of these based on that
DEPEND="
	app-accessibility/at-spi2-core:2
	dev-libs/glib:2
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/pango
"
RDEPEND="${DEPEND}"
BDEPEND="
	dev-lang/lazarus
"

# these stolen from app-misc/doublecmd::guru again, but modified so much it
# might as well not be stolen
QA_PRESTRIPPED="/usr/bin/ddrescueview"

src_compile() {
	# lazarusdir stolen from app-misc/doublecmd::guru
	lazbuild --lazarusdir=/usr/share/lazarus ./source/ddrescueview.lpi || die "build failed"
}

src_install() {
	dobin ./source/ddrescueview
	doman ./resources/linux/man/man1/ddrescueview.1
	domenu ./resources/linux/applications/ddrescueview.desktop
	for i in 16 22 24 32 48 64 128 256; do
		doicon -s "$i" ./resources/linux/icons/hicolor/"${i}x${i}"/apps/ddrescueview.png
	done
}