Gentoo Packages

# Copyright 2024-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module

# bumping: watch Makefile for changes, and update src_install, src_test, and
# maybe src_compile accordingly

DESCRIPTION="Interactive jq tool"
HOMEPAGE="https://codeberg.org/gpanders/ijq"
# TODO: 9999
SRC_URI="
	https://codeberg.org/gpanders/ijq/archive/v${PV}.tar.gz -> ${P}.tar.gz
	mirror://jacksonchen666/${P}-vendor.tar.xz
"
# TODO: unbundling? (3 occurrences of #cgo but build success)

S="${WORKDIR}/${PN}"

LICENSE="GPL-3+"
# go deps, checked ijq 1.1.2
LICENSE+=" BSD MIT Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64"

#DEPEND=""
RDEPEND="
	${DEPEND}
	app-misc/jq
"
BDEPEND="
	app-text/scdoc
	>=dev-lang/go-1.26
"

src_prepare() {
	default
	# remove seemingly stripping related flags
	sed -i 's/-ldflags="-s -w /-ldflags="/' Makefile || die "makefile sed failed"
}

src_compile() {
	emake VERSION="${PVR}" ijq
	emake docs
}

src_install() {
	dodoc README.md
	dobin ijq
	doman ijq.1
}

src_test() {
	ego test -v .
}