gui-terms/kwi - 0.1.0 (kde)

Search

Install

Install this version:

emerge -a =gui-terms/kwi-0.1.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =gui-terms/kwi-0.1.0

Or alternatively:

emerge --autounmask-write -a =gui-terms/kwi-0.1.0

Package Information

Description:
Modern and fast terminal for KDE Plasma and other desktops
Homepage:
https://invent.kde.org/utilities/kwi
License:
|| ( GPL-2 GPL-3 ) GPL-2+ || ( LGPL-2.1 LGPL-3 ) LGPL-2+ BSD-2 CC-BY-SA-4.0 CC0-1.0

Ebuild Details

Version EAPI Keywords Slot
0.1.0 8 ~amd64 0
View Raw Ebuild
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_TEST="true"
KDE_ORG_CATEGORY="utilities"
KDE_VERIFY_SIG=1
KFMIN=6.29.0
QTMIN=6.11.2
inherit ecm kde.org

if [[ ${KDE_BUILD_TYPE} = release ]]; then
	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
	if [[ -n ${KDE_VERIFY_SIG} ]]; then
		SRC_URI+=" verify-sig? ( mirror://kde/stable/${PN}/${PV}/${P}.tar.xz.sig )"
	fi
	KEYWORDS="~amd64"
fi

DESCRIPTION="Modern and fast terminal for KDE Plasma and other desktops"
HOMEPAGE="https://invent.kde.org/utilities/kwi"

LICENSE="
	|| ( GPL-2 GPL-3 ) GPL-2+
	|| ( LGPL-2.1 LGPL-3 ) LGPL-2+
	BSD-2 CC-BY-SA-4.0 CC0-1.0
"
SLOT="0"
IUSE="+app +kpart"
REQUIRED_USE="|| ( app kpart )"

# qtbase:= Qt6GuiPrivate
DEPEND="
	>=dev-libs/kirigami-addons-1.11:6
	>=dev-libs/libghostty-vt-1.0.1:=
	>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,network,widgets]
	>=dev-qt/qtdeclarative-${QTMIN}:6
	>=dev-qt/qtsvg-${QTMIN}:6
	>=kde-frameworks/kconfig-${KFMIN}:6
	>=kde-frameworks/kcolorscheme-${KFMIN}:6
	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/kguiaddons-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/kirigami-${KFMIN}:6
	>=kde-frameworks/knotifications-${KFMIN}:6
	>=kde-frameworks/kpty-${KFMIN}:6
	>=kde-frameworks/kwindowsystem-${KFMIN}:6
	app? (
		>=dev-libs/kirigami-app-components-1.1:6
		>=kde-frameworks/kdbusaddons-${KFMIN}:6
	)
	kpart? (
		>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
		>=kde-frameworks/kiconthemes-${KFMIN}:6
		>=kde-frameworks/kparts-${KFMIN}:6
		>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
		>=kde-frameworks/kxmlgui-${KFMIN}:6
	)
"
# QML runtime dependencies, see ecm_find_qmlmodule in CMakeLists.txt
RDEPEND="${DEPEND}
	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
	app? ( >=kde-frameworks/kitemmodels-${KFMIN}:6 )
"
BDEPEND="
	>=dev-qt/qtshadertools-${QTMIN}:6
	virtual/pkgconfig
"

src_configure() {
	local mycmakeargs=(
		-DBUILD_APP=$(usex app)
		-DBUILD_KPART=$(usex kpart)
	)
	ecm_src_configure
}

USE Flags

Manage flags for this package: euse -i <flag> -p gui-terms/kwi | euse -E <flag> -p gui-terms/kwi | euse -D <flag> -p gui-terms/kwi

Global/Standard Flags

app
❓ Default: Enabled (+)
kpart
❓ Default: Enabled (+)

Inherited Eclasses

ecm

Dependencies

DEPEND

	>=dev-libs/kirigami-addons-1.11:6
	>=dev-libs/libghostty-vt-1.0.1:=
	>=dev-qt/qtbase-6.11.2:6=[concurrent,dbus,gui,network,widgets]
	>=dev-qt/qtdeclarative-6.11.2:6
	>=dev-qt/qtsvg-6.11.2:6
	>=kde-frameworks/kconfig-6.29.0:6
	>=kde-frameworks/kcolorscheme-6.29.0:6
	>=kde-frameworks/kconfigwidgets-6.29.0:6
	>=kde-frameworks/kcoreaddons-6.29.0:6
	>=kde-frameworks/kguiaddons-6.29.0:6
	>=kde-frameworks/ki18n-6.29.0:6
	>=kde-frameworks/kio-6.29.0:6
	>=kde-frameworks/kirigami-6.29.0:6
	>=kde-frameworks/knotifications-6.29.0:6
	>=kde-frameworks/kpty-6.29.0:6
	>=kde-frameworks/kwindowsystem-6.29.0:6
	app? (
		>=dev-libs/kirigami-app-components-1.1:6
		>=kde-frameworks/kdbusaddons-6.29.0:6
	)
	kpart? (
		>=dev-qt/qtdeclarative-6.11.2:6[widgets]
		>=kde-frameworks/kiconthemes-6.29.0:6
		>=kde-frameworks/kparts-6.29.0:6
		>=kde-frameworks/kwidgetsaddons-6.29.0:6
		>=kde-frameworks/kxmlgui-6.29.0:6
	)

RDEPEND

	>=dev-libs/kirigami-addons-1.11:6
	>=dev-libs/libghostty-vt-1.0.1:=
	>=dev-qt/qtbase-6.11.2:6=[concurrent,dbus,gui,network,widgets]
	>=dev-qt/qtdeclarative-6.11.2:6
	>=dev-qt/qtsvg-6.11.2:6
	>=kde-frameworks/kconfig-6.29.0:6
	>=kde-frameworks/kcolorscheme-6.29.0:6
	>=kde-frameworks/kconfigwidgets-6.29.0:6
	>=kde-frameworks/kcoreaddons-6.29.0:6
	>=kde-frameworks/kguiaddons-6.29.0:6
	>=kde-frameworks/ki18n-6.29.0:6
	>=kde-frameworks/kio-6.29.0:6
	>=kde-frameworks/kirigami-6.29.0:6
	>=kde-frameworks/knotifications-6.29.0:6
	>=kde-frameworks/kpty-6.29.0:6
	>=kde-frameworks/kwindowsystem-6.29.0:6
	app? (
		>=dev-libs/kirigami-app-components-1.1:6
		>=kde-frameworks/kdbusaddons-6.29.0:6
	)
	kpart? (
		>=dev-qt/qtdeclarative-6.11.2:6[widgets]
		>=kde-frameworks/kiconthemes-6.29.0:6
		>=kde-frameworks/kparts-6.29.0:6
		>=kde-frameworks/kwidgetsaddons-6.29.0:6
		>=kde-frameworks/kxmlgui-6.29.0:6
	)

	>=kde-frameworks/qqc2-desktop-style-6.29.0:6
	app? ( >=kde-frameworks/kitemmodels-6.29.0:6 )

BDEPEND

	>=dev-qt/qtshadertools-6.11.2:6
	virtual/pkgconfig

Manifest for 0.1.0

Type File Size Source URLs
DIST kwi-0.1.0.tar.xz 311548 bytes mirror://kde/stable/kwi/0.1.0/kwi-0.1.0.tar.xz
DIST kwi-0.1.0.tar.xz.sig 228 bytes mirror://kde/stable/kwi/0.1.0/kwi-0.1.0.tar.xz.sig