Gentoo Packages

Search

Install

Install this version:

emerge -a =kde-apps/gwenview-26.04.0

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =kde-apps/gwenview-26.04.0

Or alternatively:

emerge --autounmask-write -a =kde-apps/gwenview-26.04.0

Package Information

Description:: Image viewer by KDE
Homepage:: https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview
License:: GPL-2+ handbook? ( FDL-1.2 )

Ebuild Details

Version	EAPI	Keywords	Slot
26.04.0	8	~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86	6

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=6.22.0
QTMIN=6.10.1
inherit ecm gear.kde.org optfeature xdg

DESCRIPTION="Image viewer by KDE"
HOMEPAGE="https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview"

LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="activities +annotate fits +mpris raw semantic-desktop share X"

# requires running environment
RESTRICT="test"

# slot op: includes qpa/qplatformnativeinterface.h, qtx11extras_p.h
COMMON_DEPEND="
	dev-libs/wayland
	>=dev-qt/qtbase-${QTMIN}:6=[gui,opengl,wayland,widgets]
	>=dev-qt/qtmultimedia-${QTMIN}:6
	>=dev-qt/qtsvg-${QTMIN}:6
	>=kde-frameworks/kcompletion-${KFMIN}:6
	>=kde-frameworks/kconfig-${KFMIN}:6
	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/kcrash-${KFMIN}:6
	>=kde-frameworks/kguiaddons-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kiconthemes-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/kitemmodels-${KFMIN}:6
	>=kde-frameworks/kitemviews-${KFMIN}:6
	>=kde-frameworks/kjobwidgets-${KFMIN}:6
	>=kde-frameworks/knotifications-${KFMIN}:6
	>=kde-frameworks/kparts-${KFMIN}:6
	>=kde-frameworks/kservice-${KFMIN}:6
	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
	>=kde-frameworks/kxmlgui-${KFMIN}:6
	>=kde-frameworks/solid-${KFMIN}:6
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libjpeg-turbo:=
	media-libs/libpng:0=
	media-libs/tiff:=
	activities? ( kde-plasma/plasma-activities:6= )
	annotate? (
		>=media-libs/kcolorpicker-0.3.1
		>=media-libs/kimageannotator-0.7.1
	)
	fits? ( sci-libs/cfitsio )
	mpris? ( >=dev-qt/qtbase-${QTMIN}:6[dbus] )
	raw? ( >=kde-apps/libkdcraw-${PVCUT}:6 )
	semantic-desktop? (
		>=kde-frameworks/baloo-${KFMIN}:6
		>=kde-frameworks/kfilemetadata-${KFMIN}:6
	)
	share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
	X? (
		>=dev-qt/qtbase-${QTMIN}:6=[X]
		x11-libs/libX11
	)
"
DEPEND="${COMMON_DEPEND}
	dev-libs/wayland-protocols
	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
	>=kde-frameworks/kwindowsystem-${KFMIN}:6
"
RDEPEND="${COMMON_DEPEND}
	>=dev-qt/qtimageformats-${QTMIN}:6
	>=kde-apps/thumbnailers-${PVCUT}:6
	>=kde-frameworks/kimageformats-${KFMIN}:6
"
BDEPEND="
	>=dev-qt/qtbase-${QTMIN}:6[wayland]
	dev-util/wayland-scanner
"

src_prepare() {
	ecm_src_prepare
	if ! use mpris; then
		# FIXME: upstream a better solution
		sed -e "/set(HAVE_QTDBUS/s/\${Qt6DBus_FOUND}/0/" -i CMakeLists.txt || die
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake_use_find_package activities PlasmaActivities)
		-DGWENVIEW_IMAGEANNOTATOR=$(usex annotate)
		$(cmake_use_find_package fits CFitsio)
		$(cmake_use_find_package raw KDcrawQt6)
		-DGWENVIEW_SEMANTICINFO_BACKEND=$(usex semantic-desktop Baloo None)
		$(cmake_use_find_package share KF6Purpose)
		-DWITHOUT_X11=$(usex !X)
	)
	ecm_src_configure
}

pkg_postinst() {
	if [[ -z "${REPLACING_VERSIONS}" ]]; then
		optfeature "SVG support" "kde-apps/svgpart:${SLOT}"
	fi
	xdg_pkg_postinst
}

USE Flags

Manage flags for this package: euse -i <flag> -p kde-apps/gwenview | euse -E <flag> -p kde-apps/gwenview | euse -D <flag> -p kde-apps/gwenview

Global/Standard Flags

activities

annotate

fits

mpris

raw

semantic-desktop

share

X

Inherited Eclasses

ecm

gear.kde.org

optfeature

xdg

Dependencies

DEPEND

	dev-libs/wayland
	>=dev-qt/qtbase-:6=[gui,opengl,wayland,widgets]
	>=dev-qt/qtmultimedia-:6
	>=dev-qt/qtsvg-:6
	>=kde-frameworks/kcompletion-:6
	>=kde-frameworks/kconfig-:6
	>=kde-frameworks/kconfigwidgets-:6
	>=kde-frameworks/kcoreaddons-:6
	>=kde-frameworks/kcrash-:6
	>=kde-frameworks/kguiaddons-:6
	>=kde-frameworks/ki18n-:6
	>=kde-frameworks/kiconthemes-:6
	>=kde-frameworks/kio-:6
	>=kde-frameworks/kitemmodels-:6
	>=kde-frameworks/kitemviews-:6
	>=kde-frameworks/kjobwidgets-:6
	>=kde-frameworks/knotifications-:6
	>=kde-frameworks/kparts-:6
	>=kde-frameworks/kservice-:6
	>=kde-frameworks/kwidgetsaddons-:6
	>=kde-frameworks/kxmlgui-:6
	>=kde-frameworks/solid-:6
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libjpeg-turbo:=
	media-libs/libpng:0=
	media-libs/tiff:=
	activities? ( kde-plasma/plasma-activities:6= )
	annotate? (
		>=media-libs/kcolorpicker-0.3.1
		>=media-libs/kimageannotator-0.7.1
	)
	fits? ( sci-libs/cfitsio )
	mpris? ( >=dev-qt/qtbase-:6[dbus] )
	raw? ( >=kde-apps/libkdcraw-$(ver_cut:6 )
	semantic-desktop? (
		>=kde-frameworks/baloo-:6
		>=kde-frameworks/kfilemetadata-:6
	)
	share? ( >=kde-frameworks/purpose-:6 )
	X? (
		>=dev-qt/qtbase-:6=[X]
		x11-libs/libX11
	)

	dev-libs/wayland-protocols
	>=dev-qt/qtbase-6.10.1:6[concurrent]
	>=kde-frameworks/kwindowsystem-6.22.0:6

RDEPEND

	dev-libs/wayland
	>=dev-qt/qtbase-6.10.1:6=[gui,opengl,wayland,widgets]
	>=dev-qt/qtmultimedia-:6
	>=dev-qt/qtsvg-:6
	>=kde-frameworks/kcompletion-6.22.0:6
	>=kde-frameworks/kconfig-:6
	>=kde-frameworks/kconfigwidgets-:6
	>=kde-frameworks/kcoreaddons-:6
	>=kde-frameworks/kcrash-:6
	>=kde-frameworks/kguiaddons-:6
	>=kde-frameworks/ki18n-:6
	>=kde-frameworks/kiconthemes-:6
	>=kde-frameworks/kio-:6
	>=kde-frameworks/kitemmodels-:6
	>=kde-frameworks/kitemviews-:6
	>=kde-frameworks/kjobwidgets-:6
	>=kde-frameworks/knotifications-:6
	>=kde-frameworks/kparts-:6
	>=kde-frameworks/kservice-:6
	>=kde-frameworks/kwidgetsaddons-:6
	>=kde-frameworks/kxmlgui-:6
	>=kde-frameworks/solid-:6
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libjpeg-turbo:=
	media-libs/libpng:0=
	media-libs/tiff:=
	activities? ( kde-plasma/plasma-activities:6= )
	annotate? (
		>=media-libs/kcolorpicker-0.3.1
		>=media-libs/kimageannotator-0.7.1
	)
	fits? ( sci-libs/cfitsio )
	mpris? ( >=dev-qt/qtbase-:6[dbus] )
	raw? ( >=kde-apps/libkdcraw-$(ver_cut:6 )
	semantic-desktop? (
		>=kde-frameworks/baloo-:6
		>=kde-frameworks/kfilemetadata-:6
	)
	share? ( >=kde-frameworks/purpose-:6 )
	X? (
		>=dev-qt/qtbase-:6=[X]
		x11-libs/libX11
	)

	>=dev-qt/qtimageformats-6.10.1:6
	>=kde-apps/thumbnailers-$(ver_cut:6
	>=kde-frameworks/kimageformats-6.22.0:6

BDEPEND

	>=dev-qt/qtbase-6.10.1:6[wayland]
	dev-util/wayland-scanner

kde-apps/gwenview - 26.04.0 (kde)