Gentoo Packages

Search

Install

Install this version:

emerge -a =kde-apps/ksystemlog-26.03.90

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =kde-apps/ksystemlog-26.03.90

Or alternatively:

emerge --autounmask-write -a =kde-apps/ksystemlog-26.03.90

Package Information

Description:: System log viewer by KDE
Homepage:: https://apps.kde.org/ksystemlog/
License:: GPL-2

Ebuild Details

Version	EAPI	Keywords	Slot
26.03.90	8	~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86	6

View Raw Ebuild

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
KFMIN=6.22.0
QTMIN=6.10.1
inherit ecm gear.kde.org

DESCRIPTION="System log viewer by KDE"
HOMEPAGE="https://apps.kde.org/ksystemlog/"

LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="audit kdesu systemd"

DEPEND="
	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
	>=kde-frameworks/karchive-${KFMIN}:6
	>=kde-frameworks/kcompletion-${KFMIN}:6
	>=kde-frameworks/kconfig-${KFMIN}:6
	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/kcrash-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/kitemviews-${KFMIN}:6
	>=kde-frameworks/ktextwidgets-${KFMIN}:6
	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
	>=kde-frameworks/kxmlgui-${KFMIN}:6
	audit? ( sys-process/audit )
	systemd? (
		>=dev-qt/qtbase-${QTMIN}:6[network]
		sys-apps/systemd:=
	)
"
RDEPEND="${DEPEND}"

src_prepare() {
	ecm_src_prepare
	if ! use kdesu; then
		sed -e "/^X-KDE-SubstituteUID/s:true:false:" \
			-i src/org.kde.ksystemlog.desktop || die
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake_use_find_package audit Audit)
		$(cmake_use_find_package systemd Journald)
	)
	ecm_src_configure
}

pkg_postinst() {
	use kdesu || elog "Will show only user readable logs without USE=kdesu (only in X)."
	use kdesu && elog "Cannot be launched from application menu in Wayland with USE=kdesu."
}

USE Flags

Manage flags for this package: euse -i <flag> -p kde-apps/ksystemlog | euse -E <flag> -p kde-apps/ksystemlog | euse -D <flag> -p kde-apps/ksystemlog

Global/Standard Flags

audit

kdesu

systemd

Inherited Eclasses

ecm

gear.kde.org

Dependencies

DEPEND

	>=dev-qt/qtbase-6.10.1:6[gui,widgets]
	>=kde-frameworks/karchive-6.22.0:6
	>=kde-frameworks/kcompletion-:6
	>=kde-frameworks/kconfig-:6
	>=kde-frameworks/kconfigwidgets-:6
	>=kde-frameworks/kcoreaddons-:6
	>=kde-frameworks/kcrash-:6
	>=kde-frameworks/ki18n-:6
	>=kde-frameworks/kio-:6
	>=kde-frameworks/kitemviews-:6
	>=kde-frameworks/ktextwidgets-:6
	>=kde-frameworks/kwidgetsaddons-:6
	>=kde-frameworks/kxmlgui-:6
	audit? ( sys-process/audit )
	systemd? (
		>=dev-qt/qtbase-:6[network]
		sys-apps/systemd:=
	)

RDEPEND

	>=dev-qt/qtbase-6.10.1:6[gui,widgets]
	>=kde-frameworks/karchive-6.22.0:6
	>=kde-frameworks/kcompletion-:6
	>=kde-frameworks/kconfig-:6
	>=kde-frameworks/kconfigwidgets-:6
	>=kde-frameworks/kcoreaddons-:6
	>=kde-frameworks/kcrash-:6
	>=kde-frameworks/ki18n-:6
	>=kde-frameworks/kio-:6
	>=kde-frameworks/kitemviews-:6
	>=kde-frameworks/ktextwidgets-:6
	>=kde-frameworks/kwidgetsaddons-:6
	>=kde-frameworks/kxmlgui-:6
	audit? ( sys-process/audit )
	systemd? (
		>=dev-qt/qtbase-:6[network]
		sys-apps/systemd:=
	)

kde-apps/ksystemlog - 26.03.90 (kde)