Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_HANDBOOK="forceoptional"
ECM_TEST="true"
KDE_ORG_CATEGORY="network"
KFMIN=6.22.0
PVCUT=$(ver_cut 1-3)
QTMIN=6.10.1
inherit ecm gear.kde.org

DESCRIPTION="KIO worker for Google Drive service"
HOMEPAGE="https://apps.kde.org/kio_gdrive/"

LICENSE="GPL-2+"
SLOT="6"
KEYWORDS=""
IUSE="+share"

COMMON_DEPEND="
	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
	>=kde-apps/kaccounts-integration-${PVCUT}:6
	>=kde-apps/libkgapi-${PVCUT}:6=
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/knotifications-${KFMIN}:6
	share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
"
DEPEND="${COMMON_DEPEND}
	>=dev-qt/qtbase-${QTMIN}:6[network]
"
RDEPEND="${COMMON_DEPEND}
	!kde-misc/kio-gdrive:5
	!kde-misc/kio-gdrive-common
	kde-apps/kaccounts-providers:6
"
BDEPEND="
	dev-util/intltool
	kde-apps/kaccounts-integration:6
"

src_configure() {
	local mycmakeargs=(
		$(cmake_use_find_package share KF6Purpose)
	)
	ecm_src_configure
}