Gentoo Packages

# Copyright 2021-2026 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs edo

if [[ "${PV}" = 9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://anongit.hacktivis.me/git/utils-std.git"
else
	VERIFY_SIG_METHOD=signify
	inherit verify-sig

	SRC_URI="
		https://distfiles.hacktivis.me/releases/utils-std/${P}.tar.gz
		verify-sig? ( https://distfiles.hacktivis.me/releases/utils-std/${P}.tar.gz.sign )
	"

	KEYWORDS="~amd64 ~arm64 ~riscv"
fi

DESCRIPTION="Collection of commonly available Unix tools"
HOMEPAGE="https://hacktivis.me/projects/utils-std"
# CC0-1.0 OR WTFPL -> CC0-1.0 already needed so implify into CC0-1.0
# GFDL-1.1 -> only used for lsb_commands.txt which isn't used here
LICENSE="MPL-2.0 CC0-1.0 0BSD BSD BSD-2 BSD-4 MIT"
SLOT="0"
IUSE="md5sum multicall test static system"

RESTRICT="
	!test? ( test )
	multicall? ( test )
"

RDEPEND="
	system? (
		!sys-apps/coreutils[system(+)]
		!sys-apps/diffutils[system(+)]
		!sys-process/time[system(+)]
		!sys-apps/which
	)
"
BDEPEND="
	app-alternatives/yacc
	test? ( dev-util/cram )
"

if [[ "${PV}" != 9999* ]]
then
	BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2026 )"

	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2026.pub"

	src_unpack() {
		if use verify-sig; then
			# Too many levels of symbolic links workaround
			cd "${WORKDIR}" || die
			cp "${DISTDIR}/${P}.tar.gz" "${DISTDIR}/${P}.tar.gz.sign" "${WORKDIR}/" || die
			verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
			unpack "${WORKDIR}/${P}.tar.gz"
			rm "${WORKDIR}/${P}.tar.gz"
		else
			default
		fi
	}
fi

src_configure() {
	export NO_BWRAP=1
	tc-export CC AR

	local myconfargs=(
		PREFIX=$(usex system '/usr' '/opt/lanodan')
	)

	use static && myconfargs+=( LDSTATIC="-static-pie" )
	use md5sum && myconfargs+=( ENABLE_MD5SUM=1 )

	edo ./configure "${myconfargs[@]}" || die
}

src_compile() {
	if use multicall; then
		emake -f Makefile.multicall
	else
		emake
	fi
}

src_test() {
	if use multicall; then
		emake -f Makefile.multicall check
	else
		emake check
	fi
}

src_install() {
	if use multicall; then
		emake -f Makefile.multicall install DESTDIR="${D}"
	else
		emake install DESTDIR="${D}"
	fi

	# before 50baselayout
	use system || newenvd - 40lanodan <<-EOF
		PATH="/opt/lanodan/bin:/opt/lanodan/sbin"
		ROOTPATH="/opt/lanodan/bin:/opt/lanodan/sbin"
		MANPATH="/opt/lanodan/share/man"
	EOF
}