Gentoo Packages

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Fill your console with Hollywood melodrama technobabble"
HOMEPAGE="https://hollywood.computer"
SRC_URI="https://github.com/dustinkirkland/hollywood/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+hollywood +wallstreet"

# TODO: speedometer, ticker

DEPEND="
	app-misc/byobu
	app-misc/tmux

	hollywood? (
		app-admin/apg
		sys-process/atop
		sys-apps/bat
		net-analyzer/bmon
		sys-apps/util-linux
		app-admin/ccze
		app-misc/cmatrix
		app-misc/figlet
		sys-process/htop
		media-gfx/jp2a
		sys-apps/plocate
		sys-apps/moreutils
		media-video/mplayer
		net-misc/openssh
		sys-apps/pv
		dev-python/pygments
		app-text/tree
	)

	wallstreet? (
		media-libs/libcaca
		net-news/newsboat
		net-news/rsstail
		net-misc/wget
		virtual/w3m
	)
"

src_install() {
	if use hollywood; then
		dobin bin/hollywood

		exeinto /usr/lib/hollywood
		doexe lib/hollywood/*

		doman share/man/man1/hollywood.1

		insinto /usr/share
		doins -r share/hollywood
	fi

	if use wallstreet; then
		dobin bin/wallstreet

		exeinto /usr/lib/wallstreet
		doexe lib/wallstreet/*

		doman share/man/man1/wallstreet.1

		insinto /usr/share
		doins -r share/wallstreet
	fi
}