Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{13..15} )

inherit cmake python-any-r1 custom-cflags

DESCRIPTION="XGQT.Org utils"
HOMEPAGE="https://codeberg.org/xgqt/xgqt-cpp-app-xo-utils/"

if [[ "${PV}" == *9999* ]] ; then
	inherit git-r3
	MAJOR="1"
	EGIT_REPO_URI="https://codeberg.org/xgqt/xgqt-cpp-app-${PN}"
	S="${WORKDIR}/${PN}/code/source/v${MAJOR}"
else
	MAJOR="$(ver_cut 1)"
	SRC_URI="https://codeberg.org/xgqt/xgqt-cpp-app-${PN}/archive/${PV}.tar.gz
		-> ${P}.codeberg.tar.gz"
	S="${WORKDIR}/xgqt-cpp-app-${PN}/code/source/v${MAJOR}"
	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
fi

LICENSE="MPL-2.0"
SLOT="0/${MAJOR}"
IUSE="doc test"
RESTRICT="!test? ( test )"

RDEPEND="
	app-arch/libarchive:=
	dev-cpp/cli11:=
	dev-libs/libyaml:=
	dev-vcs/git
"
DEPEND="
	${RDEPEND}
"
BDEPEND="
	${PYTHON_DEPS}
	doc? (
		app-text/doxygen
	)
	test? (
		dev-cpp/gtest
	)
"

pkg_setup() {
	python-any-r1_pkg_setup
}

src_configure() {
	custom-cflags_src_configure

	local -a mycmakeargs=(
		-DCMAKE_BUILD_TYPE="${CMAKE_BUILD_TYPE}"
		-DBUILD_DOCS="$(usex doc)"
		-DBUILD_TESTING="$(usex test)"
		-DWITH_CCACHE="OFF"

		-DWITH_SYSTEM_CLI11="ON"
		-DWITH_SYSTEM_GTEST="ON"
		-DBUILD_BASE="ON"
		-DBUILD_GIT="ON"
	)
	cmake_src_configure
}