Gentoo Packages

# Copyright 2026 Nadeŭka <me+oss@nadevko.cc>
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FIREFOX_BIN_SLOT=esr
FIREFOX_BIN_ISESR=1
VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/mozilla.asc
inherit verify-sig firefox-bin

DESCRIPTION='Mozilla Firefox Web Browser, Extended Support Release'
HOMEPAGE=https://www.mozilla.org/firefox/enterprise
BASE_URI=https://archive.mozilla.org/pub/firefox/releases/${FIREFOX_BIN_PV_MOZ}
AMD64_URI=${BASE_URI}/linux-x86_64/en-US/firefox-${FIREFOX_BIN_PV_MOZ}.tar.xz
ARM64_URI=${BASE_URI}/linux-aarch64/en-US/firefox-${FIREFOX_BIN_PV_MOZ}.tar.xz
SRC_URI="
	amd64? ( ${AMD64_URI} -> ${P}-amd64.tar.xz )
	arm64? ( ${ARM64_URI} -> ${P}-arm64.tar.xz )
	verify-sig? (
		amd64? ( ${AMD64_URI}.asc -> ${P}-amd64.tar.xz.asc )
		arm64? ( ${ARM64_URI}.asc -> ${P}-arm64.tar.xz.asc )
	)
"

KEYWORDS='~amd64'

RESTRICT+=' !verify-sig? ( test )'

BDEPEND+=' verify-sig? ( >=res-openpgp/mozilla-20260806 )'

FIREFOX_BIN_L10N=(
	ach af an ar ast az be bg bn br bs ca ca-valencia cak cs cy da de dsb
	el en-CA en-GB eo es-AR es-CL es-ES es-MX et eu fa ff fi fr fur fy-NL
	ga-IE gd gl gn gu-IN he hi-IN hr hsb hu hy-AM ia id is it ja ka kab kk
	km kn ko lij lt lv mk mr ms my nb-NO ne-NP nl nn-NO oc pa-IN pl pt-BR
	pt-PT rm ro ru sat sc sco si sk skr sl son sq sr sv-SE szl ta te tg th
	tl tr trs uk ur uz vi xh zh-CN zh-TW
)
FIREFOX_BIN_L10N_URI=${BASE_URI}/linux-x86_64/xpi/@LANG@.xpi
firefox-bin_set_l10n_src_uri

src_unpack() {
	if use verify-sig; then
		use amd64 && verify-sig_verify_detached "${DISTDIR}"/${P}-amd64.tar.xz{,.asc}
		use arm64 && verify-sig_verify_detached "${DISTDIR}"/${P}-arm64.tar.xz{,.asc}
	fi

	firefox-bin_src_unpack
}