Gentoo Packages

# Copyright 2026 Nadeŭka <me+oss@nadevko.cc>
# Distributed under the terms of the GNU General Public License v2
EAPI=8

inherit udev

DESCRIPTION='Program to read and control device brightness'
HOMEPAGE=https://github.com/Hummer12007/brightnessctl
SRC_URI="https://github.com/Hummer12007/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE=MIT
SLOT=0
KEYWORDS=amd64

IUSE='systemd +udev'

DEPEND='systemd? ( >=sys-apps/systemd-243 )'
RDEPEND="
	${DEPEND}
	udev? ( virtual/udev acct-group/video acct-group/input )
"
BDEPEND=virtual/pkgconfig

PATCHES=( "${FILESDIR}" )

src_compile() {
	emake $(usev systemd 'ENABLE_SYSTEMD=1')
}

src_install() {
	emake DESTDIR="${D}" \
		$(usev systemd 'ENABLE_SYSTEMD=1') UDEVDIR="$(get_udevdir)"/rules.d \
		install $(usev udev install_udev_rules)
	einstalldocs
	newinitd "${FILESDIR}"/brightnessctl.initd brightnessctl
	newconfd "${FILESDIR}"/brightnessctl.confd brightnessctl
}

pkg_postinst() {
	use udev && udev_reload

	if ! use systemd; then
		elog 'To make brightness persistent across reboots, enable the service:'
		elog '  rc-update add brightnessctl boot'
		elog '  rc-service brightnessctl start'
	fi
}

pkg_postrm() {
	use udev && udev_reload
}