Gentoo Packages

# Copyright 2026 Nadeŭka <me+oss@nadevko.cc>
# Distributed under the terms of the GNU General Public License v2
EAPI=8

inherit udev

DESCRIPTION='A program to read and control device brightness'
HOMEPAGE=https://github.com/Hummer12007/brightnessctl
SRC_URI="https://github.com/Hummer12007/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE=MIT

SLOT=0
KEYWORDS='amd64 ~arm ~arm64 ~ppc64 ~x86'
IUSE='systemd +udev'

BDEPEND=virtual/pkgconfig
DEPEND='systemd? ( >=sys-apps/systemd-243 )'
RDEPEND="
	${DEPEND}
	udev? ( virtual/udev acct-group/video acct-group/input )
"

src_prepare() {
	default
	sed -i 's|install:.*|install: all|' Makefile ||
		die 'failed to patch Makefile'
}

src_compile() {
	emake $(usev systemd 'ENABLE_SYSTEMD=1')
}

src_install() {
	emake DESTDIR="${D}" \
		$(usev systemd 'ENABLE_SYSTEMD=1') UDEVDIR="$(get_udevdir)" \
		install $(usev udev install_udev_rules)
	newinitd "${FILESDIR}"/brightnessctl.initd brightnessctl
	newconfd "${FILESDIR}"/brightnessctl.confd brightnessctl
	einstalldocs
}

pkg_postinst() {
	use udev && udev_reload

	if ! use systemd; then
		elog 'To make brightness persistent across reboots, enable the service:'
		elog '  rc-update add brightnessctl boot'
		elog '  rc-service brightnessctl start'
	fi
}

pkg_postrm() {
	use udev && udev_reload
}