Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=9

COMPOSER_INSTALL_PATH="MongoDB"
COMPOSER_VENDOR="${PN%%-*}"
COMPOSER_PKG="${PN#*-}"
COMPOSER_PN="${COMPOSER_VENDOR}/${COMPOSER_PKG}"
COMPOSER_SRC="${T}/composer/${COMPOSER_PKG}"
EGIT_SUBMODULES=( "specifications" )

inherit composer git-r3

DESCRIPTION="The Official MongoDB PHP library"
HOMEPAGE="https://github.com/mongodb/mongo-php-library"
EGIT_REPO_URI="https://github.com/mongodb/mongo-php-library.git"

LICENSE="MIT"
SLOT="0"

RDEPEND="dev-php/jean85-pretty-package-versions
	>=dev-php/pecl-mongodb-2.4.0
	dev-php/psr-log
	dev-php/symfony-polyfill-php85"

PATCHES=( "${FILESDIR}/${PN}"-2.4.0-tests-BucketFunctionalTest.patch
	"${FILESDIR}/${PN}"-2.4.0-tests-CollectionFunctionalTest.patch
	"${FILESDIR}/${PN}"-2.4.0-tests-DocumentsMatchConstraintTest.patch
	"${FILESDIR}/${PN}"-2.4.0-tests-FieldPathTest.patch
	"${FILESDIR}/${PN}"-2.4.0-tests-GetEncryptedFieldsFromServerFunctionalTest.patch
	"${FILESDIR}/${PN}"-2.4.0-tests-Operation.patch )

composer_enable_tests phpunit

src_test() {
	# unified specification tests use MongoDB fail points to simulate command errors.
	# configureFailPoint is available only when test commands are enabled.
	# functional/spec test suite creates many MongoDB collections and indexes.
	# raise the file-descriptor limit with 'ulimit -n 65536' to prevent WiredTiger from aborting with EMFILE.
	edo mongod --port 27017 --bind_ip 127.0.0.1 --nounixsocket --setParameter enableTestCommands=1 --fork \
		--dbpath="${T}" --logpath="${T}/mongod.log"
	edo php -d zend.assertions=1 -d memory_limit=512M /usr/bin/phpunit --testdox
	edo kill "$(<"${T}/mongod.lock")"
}