Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=9

COMPOSER_INSTALL_PATH="PHPUnit"
PHP_MIN_VER="8.3"
PHP_REQ_USE="xml,xmlwriter,unicode"

inherit composer git-r3

DESCRIPTION="The PHP Unit Testing framework"
HOMEPAGE="https://github.com/sebastianbergmann/phpunit"
EGIT_REPO_URI="https://github.com/sebastianbergmann/${PN}.git"

LICENSE="BSD"
SLOT="0"

RDEPEND="dev-php/myclabs-deep-copy
	>=dev-php/phar-io-manifest-2.0.4
	>=dev-php/phar-io-version-3.2.1
	dev-php/phpunit-php-code-coverage
	dev-php/phpunit-php-file-iterator
	dev-php/phpunit-php-invoker
	dev-php/phpunit-php-text-template
	dev-php/phpunit-php-timer
	dev-php/sebastian-cli-parser
	dev-php/sebastian-comparator
	>=dev-php/sebastian-diff-7
	>=dev-php/sebastian-environment-8
	dev-php/sebastian-exporter
	dev-php/sebastian-global-state
	dev-php/sebastian-object-enumerator
	dev-php/sebastian-recursion-context
	>=dev-php/sebastian-type-6
	>=dev-php/sebastian-version-6
	dev-php/staabm-side-effects-detector:0"
BDEPEND=">=dev-php/theseer-Autoload-1.29.1
	test? ( dev-php/composer )"

PATCHES=( "${FILESDIR}/${PN}"-10.5.27-autoload-resources.patch
	"${FILESDIR}/${PN}"-10.5.27-tests.patch )

DOCS=( {ChangeLog-12.5,DEPRECATIONS,README}.md )

composer_enable_tests phpunit

src_prepare() {
	composer_src_prepare

	edo phpab -q -o src/autoload.php -t "${FILESDIR}"/autoload.php.tpl src
	edo phpab -q -o tests/unit/autoload.php -t fedora2 tests/unit/
	edo phpab -q -o tests/_files/autoload.php -t fedora2 tests/_files/
	edo phpab -o tests/end-to-end/execution-order/_files/autoload.php \
		-t fedora2 tests/end-to-end/execution-order/_files/
	edo phpab -o tests/end-to-end/event/autoload.php -t fedora2 \
		tests/end-to-end/event
	edo phpab -o tests/end-to-end/regression/autoload.php -t fedora2 \
		-e tests/end-to-end/regression/4376/tests/Test.php \
		tests/end-to-end/regression
	edo phpab -o tests/end-to-end/testdox/autoload.php -t fedora2 \
		tests/end-to-end/testdox
}

src_test() {
	# paths need to be fixed to run end-to-end, skipped 6
	ephpunit --testsuite unit
}

src_install() {
	composer_src_install
	# install files into COMPOSER_INSTALL_PATH
	doins -r schema phpunit.xsd
	dobin phpunit
}