dev-python/expiringdict - 1.2.2 (oubliette)

Search

Install

Install this version:

emerge -a =dev-python/expiringdict-1.2.2

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/expiringdict-1.2.2

Or alternatively:

emerge --autounmask-write -a =dev-python/expiringdict-1.2.2

Package Information

Description:
Dictionary with auto-expiring values for caching purposes
Homepage:
https://github.com/mailgun/expiringdict/ https://pypi.org/project/expiringdict/
License:
Apache-2.0

Ebuild Details

Version EAPI Keywords Slot
1.2.2 8 ~amd64 0
View Raw Ebuild
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..15} )

inherit distutils-r1

DESCRIPTION="Dictionary with auto-expiring values for caching purposes"
HOMEPAGE="
	https://github.com/mailgun/expiringdict/
	https://pypi.org/project/expiringdict/
"
# The PyPI sdist has no tests
SRC_URI="
	https://github.com/mailgun/expiringdict/archive/refs/tags/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"

BDEPEND="
	test? (
		$(python_gen_cond_dep '
			dev-python/dill[${PYTHON_USEDEP}]
		' 3.{12..14})
	)
"

PATCHES=(
	"${FILESDIR}"/${P}-no-nose.patch
)

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# expects the OrderedDict repr of Python < 3.12
	tests/expiringdict_test.py::test_repr
)

python_test() {
	local tests=( tests/expiringdict_test.py )
	# the pickling tests need dill, which has no python3.15 yet
	python_has_version "dev-python/dill[${PYTHON_USEDEP}]" &&
		tests+=( tests/expiringdict_extended_test.py )
	epytest "${tests[@]}"
}

Inherited Eclasses

Dependencies

BDEPEND

	test? (
		$(python_gen_cond_dep '
			dev-python/dill[${PYTHON_USEDEP}]
		' 3.{12..14})
	)

Manifest for 1.2.2

Type File Size Source URLs
DIST expiringdict-1.2.2.gh.tar.gz 8782 bytes https://github.com/mailgun/expiringdict/archive/refs/tags/v1.2.2.tar.gz