dev-python/psycopg-pool - 3.3.3 (oubliette)

Search

Install

Install this version:

emerge -a =dev-python/psycopg-pool-3.3.3

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/psycopg-pool-3.3.3

Or alternatively:

emerge --autounmask-write -a =dev-python/psycopg-pool-3.3.3

Package Information

Description:
Connection Pool for Psycopg
Homepage:
https://www.psycopg.org/psycopg3/docs/advanced/pool.html https://github.com/psycopg/psycopg/ https://pypi.org/project/psycopg-pool/
License:
LGPL-3

Ebuild Details

Version EAPI Keywords Slot
3.3.3 8 ~amd64 0
View Raw Ebuild
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1

DESCRIPTION="Connection Pool for Psycopg"
HOMEPAGE="
	https://www.psycopg.org/psycopg3/docs/advanced/pool.html
	https://github.com/psycopg/psycopg/
	https://pypi.org/project/psycopg-pool/
"

SRC_URI="
	https://github.com/psycopg/psycopg/archive/pool-${PV}.tar.gz
		-> ${P}.gh.tar.gz
"
S=${WORKDIR}/psycopg-pool-${PV}

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	>=dev-python/typing-extensions-4.6[${PYTHON_USEDEP}]
"

BDEPEND="
	test? (
		dev-python/anyio[${PYTHON_USEDEP}]
	)
"

BDEPEND+=" test? ( >=dev-db/postgresql-8.1[server(+)] dev-python/psycopg:0[${PYTHON_USEDEP}] )"
EPYTEST_PLUGINS=( anyio )
distutils_enable_tests pytest

python_compile() {
	cd psycopg_pool || die
	distutils-r1_python_compile
	cd .. || die
}

src_test() {
	initdb -D "${T}"/pgsql || die
	pg_ctl -w -D "${T}"/pgsql start -o "-h '' -k '${T}'" || die
	createdb -h "${T}" test || die
	local -x PSYCOPG_TEST_DSN="host=${T} dbname=test"
	distutils-r1_src_test
	pg_ctl -w -D "${T}"/pgsql stop || die
}

python_test() {
	epytest -p no:randomly -m "not timing and not slow and not flakey" tests/pool
}

Inherited Eclasses

Dependencies

RDEPEND

	>=dev-python/typing-extensions-4.6[]

BDEPEND

	test? (
		dev-python/anyio[]
	)
  test? ( >=dev-db/postgresql-8.1[server(+)] dev-python/psycopg:0[] )

Manifest for 3.3.3

Type File Size Source URLs
DIST psycopg-pool-3.3.3.gh.tar.gz 774573 bytes https://github.com/psycopg/psycopg/archive/pool-3.3.3.tar.gz