Gentoo Packages

# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake xdg

DESCRIPTION="A simple Qt based mod manager"
HOMEPAGE="https://github.com/limo-app/limo/"
if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/limo-app/limo/"
else
	SRC_URI="
		https://github.com/limo-app/limo/archive/refs/tags/v${PV}.tar.gz
			-> ${P}.tar.gz
	"
	KEYWORDS="~amd64"
fi

LICENSE="GPL-3"
SLOT="0"

IUSE="test"
RESTRICT="test" # tests not modified to conform with libloot-0.25 behavior
#RESTRICT="!test? ( test )"

RDEPEND="
	app-arch/libarchive:=
	app-arch/lz4:=
	app-arch/unrar:=
	app-arch/zstd:=
	dev-cpp/cpr
	dev-cpp/libloot:0/0.25
	dev-libs/jsoncpp:=
	dev-libs/openssl:=
	dev-libs/pugixml
	dev-qt/qtconcurrent:5
	dev-qt/qtcore:5
	dev-qt/qtgui:5
	dev-qt/qtnetwork:5
	dev-qt/qtsvg:5
	dev-qt/qtwidgets:5
	virtual/zlib
"
DEPEND="
	${RDEPEND}
	test? (
		dev-cpp/catch
	)
"
BDEPEND="
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}"/limo-1.2.2-gcc15.patch
)

src_configure() {
	local mycmakeargs=(
		-DIS_FLATPAK=OFF
		-DUSE_SYSTEM_LIBUNRAR=ON
		-DLIMO_INSTALL_PREFIX="${EPREFIX}/usr"
		-DBUILD_TESTING=$(usex test)
	)
	cmake_src_configure
}

src_test() {
	cmake_src_test -j1
}