Gentoo Packages

Search

Install

Install this version:

emerge -a =lxqt-base/lxqt-session-9999

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =lxqt-base/lxqt-session-9999

Or alternatively:

emerge --autounmask-write -a =lxqt-base/lxqt-session-9999

Package Information

Description:: LXQt Session Manager
Homepage:: https://lxqt-project.org/
License:: LGPL-2.1 LGPL-2.1+

Ebuild Details

Version	EAPI	Keywords	Slot
9999	8	~amd64 ~arm64 ~ppc64 ~riscv ~x86	0

View Raw Ebuild

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="LXQt Session Manager"
HOMEPAGE="https://lxqt-project.org/"

MY_PV="$(ver_cut 1-2)"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
else
	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
fi

LICENSE="LGPL-2.1 LGPL-2.1+"
SLOT="0"
IUSE="+udev"

BDEPEND="
	>=dev-qt/qttools-6.6:6[linguist]
	>=dev-util/lxqt-build-tools-2.3.0
"
DEPEND="
	>=app-misc/qtxdg-tools-4.3.0
	>=dev-libs/libqtxdg-4.3.0
	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
	kde-frameworks/kwindowsystem:6[X]
	kde-plasma/layer-shell-qt:6
	=lxqt-base/liblxqt-${MY_PV}*:=
	sys-process/procps:=
	x11-libs/libX11
	x11-misc/xdg-user-dirs
	udev? ( virtual/libudev:= )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		-DWITH_LIBUDEV=$(usex udev)
	)

	cmake_src_configure
}

src_install() {
	cmake_src_install
	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1

	newenvd - 91lxqt-config-dir <<- _EOF_
		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
	_EOF_
}

USE Flags

Manage flags for this package: euse -i <flag> -p lxqt-base/lxqt-session | euse -E <flag> -p lxqt-base/lxqt-session | euse -D <flag> -p lxqt-base/lxqt-session

Global/Standard Flags

udev

Inherited Eclasses

cmake

git-r3

Dependencies

DEPEND

	>=app-misc/qtxdg-tools-4.3.0
	>=dev-libs/libqtxdg-4.3.0
	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
	kde-frameworks/kwindowsystem:6[X]
	kde-plasma/layer-shell-qt:6
	=lxqt-base/liblxqt-$(ver_cut 1-2)*:=
	sys-process/procps:=
	x11-libs/libX11
	x11-misc/xdg-user-dirs
	udev? ( virtual/libudev:= )

RDEPEND

	>=app-misc/qtxdg-tools-4.3.0
	>=dev-libs/libqtxdg-4.3.0
	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
	kde-frameworks/kwindowsystem:6[X]
	kde-plasma/layer-shell-qt:6
	=lxqt-base/liblxqt-$(ver_cut 1-2)*:=
	sys-process/procps:=
	x11-libs/libX11
	x11-misc/xdg-user-dirs
	udev? ( virtual/libudev:= )

BDEPEND

	>=dev-qt/qttools-6.6:6[linguist]
	>=dev-util/lxqt-build-tools-2.3.0

lxqt-base/lxqt-session - 9999 (qt)