Gentoo Packages

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the BSD 3-Clause License

EAPI=8

inherit desktop linux-info

DESCRIPTION="Equibop is a fork of Vesktop"
HOMEPAGE="https://github.com/Equicord/Equibop"
SRC_URI="https://github.com/Equicord/Equibop/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/Equibop-${PV}"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
RESTRICT="network-sandbox"

CONFIG_CHECK="~USER_NS"

QA_PREBUILT="opt/equibop/*"

BDEPEND="
	net-libs/nodejs[npm]
	net-libs/bun
"

RDEPEND="
	app-accessibility/at-spi2-core
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	media-libs/alsa-lib
	media-libs/mesa
	net-print/cups
	sys-apps/dbus
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libdrm
	x11-libs/libxcb
	x11-libs/libxkbcommon
	x11-libs/pango
	x11-misc/xdg-utils
"

pkg_pretend() {
	check_extra_config
}

src_compile() {
	bun install || die "Failed to install dependencies via bun"
	bun run package:dir || die "Failed to package the application"
}

src_install() {
	insinto /opt/equibop
	doins -r dist/linux-unpacked/*

	newicon static/icon.png equibop.png

	fperms +x /opt/equibop/equibop
	fperms 4755 /opt/equibop/chrome-sandbox

	make_desktop_entry /opt/equibop/equibop Equibop equibop "Network;InstantMessaging;"
	dosym -r /opt/equibop/equibop /usr/bin/equibop
}