Gentoo Packages

dev-python/django-ninja - 1.7.1 (slonko)

Search

Install

Install this version:

emerge -a =dev-python/django-ninja-1.7.1

If this version is masked, you can unmask it using the autounmask tool or standard emerge options:

autounmask =dev-python/django-ninja-1.7.1

Or alternatively:

emerge --autounmask-write -a =dev-python/django-ninja-1.7.1

Package Information

Description:
Fast Django REST Framework
Homepage:
https://django-ninja.dev/ https://github.com/vitalik/django-ninja
License:
MIT

Ebuild Details

Version EAPI Keywords Slot
1.7.1 8 ~amd64 0
View Raw Ebuild 
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1

DESCRIPTION="Fast Django REST Framework"
HOMEPAGE="
	https://django-ninja.dev/
	https://github.com/vitalik/django-ninja
"
# Upstream ships tests only in the git tree; the PyPI sdist carries neither
# tests nor docs as of 1.7.1.
SRC_URI="https://github.com/vitalik/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	dev-python/django[${PYTHON_USEDEP}]
	dev-python/pydantic[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
		dev-python/pytest-django[${PYTHON_USEDEP}]
		dev-python/psycopg[${PYTHON_USEDEP}]
	)
"

PATCHES=(
	# tests: decimal JSON schema has no pattern since pydantic 2.14
	# https://github.com/vitalik/django-ninja/commit/722b28bce, #1797
	"${FILESDIR}/${PN}-1.7.1-pydantic-2.14-test.patch"
	# Make "import ninja" safe without configured django settings: the
	# package name collides with the PyPI ninja build-tool wrapper, and
	# scikit-build-core does "from ninja import BIN_DIR" under
	# suppress(ImportError) -- django-ninja's import-time ValidationError
	# escaped it and broke cmake-based builds (pybind11). Upstream #1395.
	"${FILESDIR}/${PN}-1.7.1-import-safety.patch"
)

EPYTEST_PLUGINS=( pytest-{asyncio,django} )
distutils_enable_tests pytest

Inherited Eclasses

distutils-r1

Dependencies

RDEPEND

	dev-python/django[]
	dev-python/pydantic[]

BDEPEND

	test? (
		dev-python/pytest-asyncio[]
		dev-python/pytest-django[]
		dev-python/psycopg[]
	)

Manifest for 1.7.1

Type File Size Source URLs
DIST django-ninja-1.7.1.gh.tar.gz 3845276 bytes https://github.com/vitalik/django-ninja/archive/v1.7.1.tar.gz