Gentoo Packages

# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit renpy

DESCRIPTION="A short yuri Visual Novel set in the American Southwest"
HOMEPAGE="https://vnstudioelan.itch.io/highway-blossoms"
SRC_URI="
	highway-blossoms-unified-zip.zip
	next-exit? ( highway-blossoms-${PV}-next-exit.zip )
	r18? ( highway-blossoms-${PV}-r18.zip )
"
S="${WORKDIR}/Highway Blossoms ${PV} - Unified"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64"
IUSE="next-exit r18"
RESTRICT="bindist fetch"

BDEPEND="app-arch/unzip"

RENPY_WINDOW_ICON="${S}/game/AppIcon.png"

PATCHES=(
	"${FILESDIR}/highway-blossoms-1.2.4-syntax.patch"
	"${FILESDIR}/highway-blossoms-1.2.4-version.patch"
	"${FILESDIR}/highway-blossoms-1.2.5-isMelanieInternal.patch"
)

src_unpack() {
	default
	unpack "${WORKDIR}/"*.zip
}

src_prepare() {
	if use next-exit; then
		cp "${WORKDIR}/Highway Blossoms Next Exit ${PV} - DLC Only/nextexit.rpa" \
			game/ || die "cp failed"
	fi
	if use r18; then
		cp "${WORKDIR}/Highway Blossoms (R18) ${PV} - Patch Only/adult.rpa" \
			game/ || die "cp failed"
	fi
	renpy_src_prepare
	use r18 && eapply "${FILESDIR}/${P}-r18-syntax.patch"
}