Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{11..14} )

inherit git-r3 meson pam python-any-r1 systemd

DESCRIPTION="D-Bus service to access fingerprint readers"
HOMEPAGE="https://gitlab.freedesktop.org/libfprint/fprintd"
EGIT_REPO_URI="https://gitlab.freedesktop.org/libfprint/fprintd.git"

LICENSE="GPL-2+"
SLOT="0"
IUSE="doc +pam selinux systemd test"
RESTRICT="!test? ( test )"

RDEPEND="
	dev-libs/glib:2
	>=sys-auth/libfprint-1.94.9:2
	sys-auth/polkit
	pam? (
		sys-libs/pam
		systemd? ( sys-apps/systemd:= )
		!systemd? ( sys-auth/elogind:= )
	)
	selinux? ( sec-policy/selinux-fprintd )
"
DEPEND="
	${RDEPEND}
	test? (
		$(python_gen_any_dep '
			dev-python/python-dbusmock[${PYTHON_USEDEP}]
			dev-python/dbus-python[${PYTHON_USEDEP}]
			dev-python/pycairo[${PYTHON_USEDEP}]
			pam? ( sys-libs/pam_wrapper[${PYTHON_USEDEP}] )
		')
	)
"
BDEPEND="
	dev-lang/perl
	>=dev-util/gdbus-codegen-2.80.5-r1
	dev-util/glib-utils
	virtual/pkgconfig
	doc? (
		dev-libs/libxml2
		dev-libs/libxslt
		dev-util/gtk-doc
	)
	test? ( ${PYTHON_DEPS} )
"

python_check_deps() {
	if use pam; then
		python_has_version -d "sys-libs/pam_wrapper[${PYTHON_USEDEP}]"
	fi

	python_has_version -d "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
		python_has_version -d "dev-python/dbus-python[${PYTHON_USEDEP}]" &&
		python_has_version -d "dev-python/pycairo[${PYTHON_USEDEP}]"
}

pkg_setup() {
	use test && python-any-r1_pkg_setup
}

src_configure() {
	local emesonargs=(
		$(meson_use test tests)
		$(meson_use pam)
		-Dgtk_doc=$(usex doc true false)
		-Dman=true
		-Dsystemd_system_unit_dir=$(systemd_get_systemunitdir)
		-Dpam_modules_dir=$(getpam_mod_dir)
		-Dlibsystemd=$(usex systemd libsystemd libelogind)
	)
	meson_src_configure
}

src_install() {
	meson_src_install

	dodoc AUTHORS NEWS README TODO
	newdoc pam/README README.pam_fprintd
}

pkg_postinst() {
	elog "Please take a look at README.pam_fprintd for integration docs."
}