Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/ollybetts.asc
inherit toolchain-funcs verify-sig

MY_P="${PN}-core-${PV}"
DESCRIPTION="Xapian Probabilistic Information Retrieval library"
HOMEPAGE="https://xapian.org/"
SRC_URI="
	https://oligarchy.co.uk/xapian/${PV}/${MY_P}.tar.xz
	verify-sig? ( https://oligarchy.co.uk/xapian/${PV}/${MY_P}.tar.xz.asc )
"
S="${WORKDIR}/${MY_P}"

LICENSE="GPL-2"
SLOT="0/45" # ABI version of libxapian.so
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
IUSE="cpu_flags_x86_sse cpu_flags_x86_sse2 debug static-libs"

# ICU is automagic, so force it on for now
DEPEND="
	>=dev-libs/icu-54.1:=
	virtual/zlib:=
	!elibc_Darwin? ( !elibc_SunOS? ( sys-apps/util-linux ) )
	elibc_SunOS? ( sys-libs/libuuid )
"
RDEPEND="${DEPEND}"
BDEPEND="
	virtual/pkgconfig
	verify-sig? ( sec-keys/openpgp-keys-ollybetts )
"

DOCS=( AUTHORS HACKING PLATFORMS README NEWS )

src_configure() {
	tc-export_build_env BUILD_CC
	local -x CC_FOR_BUILD="${BUILD_CC}"

	# skip certain autoconf checks
	local -x VALGRIND=
	local -x EATMYDATA=

	local -a myconf=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
		--disable-werror
		--enable-backend-glass
		--enable-backend-honey
		--enable-backend-inmemory
		--enable-backend-remote
		--program-suffix=
		$(use_enable debug assertions)
		$(use_enable debug log)
		$(use_enable static-libs static)
	)

	if use cpu_flags_x86_sse2; then
		myconf+=( --enable-sse=sse2 )
	elif use cpu_flags_x86_sse; then
		myconf+=( --enable-sse=sse )
	else
		myconf+=( --disable-sse )
	fi

	econf "${myconf[@]}"
}

src_test() {
	local -x VERBOSE=1
	# Avoid benchmarks/timing tests
	local -x AUTOMATED_TESTING=1
	emake -Onone check
}

src_install() {
	default
	find "${ED}" -name "*.la" -type f -delete || die
}