Gentoo Packages

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

# False positives because of REQUIRE vs BACKEND options() (conditionally set)
# See bug #809314
CMAKE_WARN_UNUSED_CLI=no
inherit cmake-multilib prefix

MY_P="${PN}-soft-${PV}"

DESCRIPTION="Software implementation of the OpenAL 3D audio API"
HOMEPAGE="https://openal-soft.org/"
SRC_URI="https://openal-soft.org/openal-releases/${MY_P}.tar.bz2"
S="${WORKDIR}"/${MY_P}

# See https://github.com/kcat/openal-soft/blob/e0097c18b82d5da37248c4823fde48b6e0002cdd/BSD-3Clause
# Some components are under BSD
LICENSE="LGPL-2+ BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="
	alsa coreaudio dbus debug jack oss pipewire portaudio pulseaudio sdl sndio gui
	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
	cpu_flags_arm_neon
"

# PipeWire:
# - See bug #863200 for PipeWire minimum version
# - PW is in DEPEND although not linked against because we need configure to
# find it anyway, but no :=.
RDEPEND="
	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
	dbus? (
		sys-apps/dbus
		sys-auth/rtkit
	)
	gui? ( >=dev-qt/qtbase-6.8:6[gui,widgets] )
	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
	pipewire? ( media-video/pipewire[${MULTILIB_USEDEP}] )
	portaudio? ( media-libs/portaudio[${MULTILIB_USEDEP}] )
	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
	sdl? ( media-libs/libsdl3[${MULTILIB_USEDEP}] )
	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
"
DEPEND="
	${RDEPEND}
	oss? ( virtual/os-headers )
"

DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )

PATCHES=(
	"${FILESDIR}"/${PN}-1.25.2-gcc17.patch
)

src_prepare() {
	cmake_src_prepare
	# bug #883407
	hprefixify alc/alconfig.cpp || die
}

multilib_src_configure() {
	local mycmakeargs=(
		# We prefer linking for predictable behaviour
		-DALSOFT_DLOPEN=OFF

		# GCC 15 ICEs (bug #976806)
		-DALSOFT_ENABLE_MODULES=OFF

		# See bug #809314 for getting both options for backends
		-DALSOFT_{BACKEND,REQUIRE}_ALSA=$(usex alsa)
		-DALSOFT_{BACKEND,REQUIRE}_COREAUDIO=$(usex coreaudio)
		-DALSOFT_{BACKEND,REQUIRE}_JACK=$(usex jack)
		-DALSOFT_{BACKEND,REQUIRE}_OSS=$(usex oss)
		-DALSOFT_{BACKEND,REQUIRE}_PIPEWIRE=$(usex pipewire)
		-DALSOFT_{BACKEND,REQUIRE}_PORTAUDIO=$(usex portaudio)
		-DALSOFT_{BACKEND,REQUIRE}_PULSEAUDIO=$(usex pulseaudio)
		-DALSOFT_{BACKEND,REQUIRE}_SDL2=OFF
		-DALSOFT_{BACKEND,REQUIRE}_SDL3=$(usex sdl)
		-DALSOFT_{BACKEND,REQUIRE}_SNDIO=$(usex sndio)

		-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
		-DALSOFT_NO_CONFIG_UTIL=$(usex gui "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
		 # EXAMPLES=OFF to avoid FFmpeg dependency, bug #481670
		-DALSOFT_EXAMPLES=OFF

		-DALSOFT_RTKIT=$(multilib_native_usex dbus)
		-DALSOFT_REQUIRE_RTKIT=$(multilib_native_usex dbus)
	)

	# Avoid unused variable warnings, bug #738240
	if use amd64 || use x86 ; then
		mycmakeargs+=(
			-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
			-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
			-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
		)
	elif use arm || use arm64 ; then
		mycmakeargs+=(
			-DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon)
		)
	fi

	cmake_src_configure
}